Castlevania: Legends (GB)

Function BINtoLZ(Src,Res: PArr; Size: Longword; Mode:byte):LongWord;
Var
 ResP,SrcP,Back,MaskP,MaskN: Longword;
 Max,Cur,MaxB:Word;
Begin
 SetLength(Res^,6);
 Res^[0]:=$10;
 Res^[1]:=Size and $FF;
 Res^[2]:=(Size shr 8) and $FF;
 Res^[3]:=(Size shr 16) and $FF;
 Res^[4]:=0;
 Res^[5]:=SRC^[0];
 MaskP:=4; //Позиция маски
 ResP:=6;  //Позиция в результирующем массиве
 SrcP:=1;  //Позиция в исходном массиве
 MaskN:=7; //Позиция в маске
 Repeat
   If MaskN=0 then begin  //Смена маски
     MaskP:=ResP;
     Inc(ResP);
     SetLength(Res^,ResP);
     MaskN:=8;
   End;
   Back:=Mode+1;
   Max:=0; //Максимальный размер копируемых данных
   MaxB:=0;
   While (Back<=$1000) and (Back<=SrcP) and (Max < $F+3) and (SrcP+Max<Size) do Begin //Поиск самого длинного повторяющегося отрезка
     Cur:=0; //Текущий размер
     While (Src^[SrcP+Cur]=Src^[SrcP-Back+Cur]) and (SrcP+Cur<Size) and (Cur<$F+3) do Inc(Cur);
     If (Cur>=3) and (Cur>Max) then begin
       Max:=Cur;
       MaxB:=Back;
     End;
     Inc(Back);
   End;
   If Max=0 then begin //Если подходящий отрезок не найден
     SetLength(Res^,ResP+1);
     Res^[ResP]:=Src^[SrcP];
     Dec(MaskN);
     Inc(ResP);
     Inc(SrcP);
   End
     Else begin //Если найден
       SetLength(Res^,ResP+2);
       Res^[ResP]:=((Max-3) shl 4)+((MaxB-1) shr 8);
       Res^[ResP+1]:=(MaxB-1) and $FF;
       Inc(ResP,2);
       Inc(SrcP,Max);
       Dec(MaskN);
       Inc(Res^[MaskP],1 shl MaskN);
     end;
 Until SrcP>=Size;
 Result:=ResP;
End;